qmake教程介紹

這個(gè)教程可以教會(huì)你如何使用qmake。我們建議你看完這個(gè)教程之后讀一下qmake手冊(cè)。

開(kāi)始很簡(jiǎn)單

讓我們假設(shè)你已經(jīng)完成了你的應(yīng)用程序的一個(gè)基本實(shí)現(xiàn)，并且你已經(jīng)創(chuàng)建了下述文件：

• hello.cpp

• hello.h

• main.cpp

你可以在qt/qmake/example中發(fā)現(xiàn)這些文件。你對(duì)這個(gè)應(yīng)用程序的配置僅僅知道的另一件事是它是用Qt寫(xiě)的。首先，使用你所喜歡的純文本編輯器，在qt/qmake/tutorial中創(chuàng)建一個(gè)叫做hello.pro的文件。你所要做的第一件事是添加一些行來(lái)告訴qmake關(guān)于你所開(kāi)發(fā)的項(xiàng)目中的源文件和頭文件這一部分。

我們先把源文件添加到項(xiàng)目文件中。為了做到這點(diǎn)，你需要使用SOURCES變量。只要用SOURCES +=來(lái)開(kāi)始一行，并且把hello.cpp放到它后面。你需要寫(xiě)成這樣：

    SOURCES += hello.cpp

我們對(duì)項(xiàng)目中的每一個(gè)源文件都這樣做，直到結(jié)束：

    SOURCES += hello.cpp
    SOURCES += main.cpp

如果你喜歡使用像Make一樣風(fēng)格的語(yǔ)法，你也可以寫(xiě)成這樣，一行寫(xiě)一個(gè)源文件，并用反斜線結(jié)尾，然后再起新的一行：

    SOURCES = hello.cpp \
	      main.cpp

現(xiàn)在源文件已經(jīng)被列到項(xiàng)目文件中了，頭文件也必須添加。添加的方式和源文件一樣，除了變量名是HEADERS。

當(dāng)你做完這些時(shí)，你的項(xiàng)目文件就像現(xiàn)在這樣：

    HEADERS += hello.h
    SOURCES += hello.cpp 
    SOURCES += main.cpp 

目標(biāo)名稱(chēng)是自動(dòng)設(shè)置的，它被設(shè)置為和項(xiàng)目文件一樣的名稱(chēng)，但是為了適合平臺(tái)所需要的后綴。舉例來(lái)說(shuō)，加入項(xiàng)目文件叫做“hello.pro”，在Windows上的目標(biāo)名稱(chēng)應(yīng)該是“hello.exe”，在Unix上應(yīng)該是“hello”。如果你想設(shè)置一個(gè)不同的名字，你可以在項(xiàng)目文件中設(shè)置它：

    TARGET = helloworld

最后一步是設(shè)置CONFIG變量。因?yàn)檫@是一個(gè)Qt應(yīng)用程序，我們需要把“qt”放到CONFIG這一行中，這樣qmake才會(huì)在連接的時(shí)候添加相關(guān)的庫(kù)，并且保證moc和uic的連編行也被包含到Makefile中。

最終完成的項(xiàng)目文件應(yīng)該是這樣的：

    CONFIG += qt
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp 

你現(xiàn)在可以使用qmake來(lái)為你的應(yīng)用程序生成Makefile。在你的應(yīng)用程序目錄中，在命令行下輸入：

    qmake -o Makefile hello.pro

然后根據(jù)你所使用的編譯器輸入make或者nmake。

使應(yīng)用程序可以調(diào)試

應(yīng)用程序的發(fā)布版本不包含任何調(diào)試符號(hào)或者其它調(diào)試信息。在開(kāi)發(fā)過(guò)程中，生成一個(gè)含有相關(guān)信息的應(yīng)用程序的調(diào)試版本是很有用處的。通過(guò)在項(xiàng)目文件的CONFIG變量中添加“debug”就可以很簡(jiǎn)單地實(shí)現(xiàn)。

例如：

    CONFIG += qt debug
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp 

像前面一樣使用qmake來(lái)生成一個(gè)Makefile并且你就能夠調(diào)試你的應(yīng)用程序了。

添加特定平臺(tái)的源文件

在編了幾個(gè)小時(shí)的程序之后，你也許開(kāi)始為你的應(yīng)用程序編寫(xiě)與平臺(tái)相關(guān)的部分，并且決定根據(jù)平臺(tái)的不同編寫(xiě)不同的代碼。所以現(xiàn)在你有兩個(gè)信文件要包含到你的項(xiàng)目文件中－hello_win.cpp和hello_x11.cpp。我們不能僅僅把這兩個(gè)文件放到SOURCES變量中，因?yàn)槟菢拥脑挄?huì)把這兩個(gè)文件都加到Makefile中。所以我們?cè)谶@里需要做的是根據(jù)qmake所運(yùn)行的平臺(tái)來(lái)使用相應(yīng)的作用域來(lái)進(jìn)行處理。

為Windows平臺(tái)添加的依賴(lài)平臺(tái)的文件的簡(jiǎn)單的作用域看起來(lái)就像這樣：

    win32 {
	SOURCES += hello_win.cpp
    }

所以如果qmake運(yùn)行在Windows上的時(shí)候，它就會(huì)把hello_win.cpp添加到源文件列表中。如果qmake運(yùn)行在其它平臺(tái)上的時(shí)候，它會(huì)很簡(jiǎn)單地把這部分忽略。現(xiàn)在接下來(lái)我們要做的就是添加一個(gè)X11依賴(lài)文件的作用域。

當(dāng)你做完了這部分，你的項(xiàng)目文件應(yīng)該和這樣差不多：

    CONFIG += qt debug
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp 
    win32 {
	SOURCES += hello_win.cpp
    }
    x11 {
	SOURCES += hello_x11.cpp
    }

像前面一樣使用qmake來(lái)生成Makefile。

如果一個(gè)文件不存在，停止qmake

如果某一個(gè)文件不存在的時(shí)候，你也許不想生成一個(gè)Makefile。我們可以通過(guò)使用exists()函數(shù)來(lái)檢查一個(gè)文件是否存在。我們可以通過(guò)使用error()函數(shù)把正在運(yùn)行的qmake停下來(lái)。這和作用域的工作方式一樣。只要很簡(jiǎn)單地用這個(gè)函數(shù)來(lái)替換作用域條件。對(duì)main.cpp文件的檢查就像這樣：

    !exists( main.cpp ) {
	error( "No main.cpp file found" )
    }

“!”用來(lái)否定這個(gè)測(cè)試，比如，如果文件存在，exists( main.cpp )是真，如果文件不存在，!exists( main.cpp )是真。

    CONFIG += qt debug
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp 
    win32 {
	SOURCES += hello_win.cpp
    }
    x11 {
	SOURCES += hello_x11.cpp
    }
    !exists( main.cpp ) {
	error( "No main.cpp file found" )
    }

像前面一樣使用qmake來(lái)生成Makefile。如果你臨時(shí)改變main.cpp的名稱(chēng)，你會(huì)看到信息，并且qmake會(huì)停止處理。

檢查多于一個(gè)的條件

假設(shè)你使用Windows并且當(dāng)你在命令行運(yùn)行你的應(yīng)用程序的時(shí)候你想能夠看到qDebug()語(yǔ)句。除非你在連編你的程序的時(shí)候使用console設(shè)置，你不會(huì)看到輸出。我們可以很容易地把console添加到CONFIG行中，這樣在Windows下，Makefile就會(huì)有這個(gè)設(shè)置。但是如果告訴你我們只是想在當(dāng)我們的應(yīng)用程序運(yùn)行在Windows下并且當(dāng)debug已經(jīng)在CONFIG行中的時(shí)候，添加console。這需要兩個(gè)嵌套的作用域；只要生成一個(gè)作用域，然后在它里面再生成另一個(gè)。把設(shè)置放在最里面的作用域里，就像這樣：

    win32 {
	debug {
	    CONFIG += console
	}
    }

嵌套的作用域可以使用冒號(hào)連接起來(lái)，所以最終的項(xiàng)目文件看起來(lái)像這樣：

    CONFIG += qt debug
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp 
    win32 {
	SOURCES += hello_win.cpp
    }
    x11 {
	SOURCES += hello_x11.cpp
    }
    !exists( main.cpp ) {
	error( "No main.cpp file found" )
    }
    win32:debug {
	CONFIG += console
    }

就這些了！你現(xiàn)在已經(jīng)完成了qmake的教程，并且已經(jīng)準(zhǔn)備好為你的開(kāi)發(fā)項(xiàng)目寫(xiě)項(xiàng)目文件了。

<!-- eof -->